Run ATITool without install!?

[MindlessOath]

Portable ATI tool based on 0.26

ok im trying to run ATITool off my usbkey without the install.
im having an issue because of the driver/service that the installer installs.

Can i get a version without the install so that i can run it off an usb key? or can i get some help to make it work? im not looking at 100% functionality without the install, but i would like to have most functions - i dont care much about the plugins etc.

sofar i have this in my NSIS script... http://forums.winamp.com/showthread.php?threadid=248886

!define SNAME "Portable ATITool"
!include "Registry.nsh"

CRCCheck off
AutoCloseWindow True
SilentInstall silent
WindowIcon off
XPSTYLE on 

Name "${SNAME}"
Icon "${SNAME}.ico"
Caption "${SNAME} Launcher"
OutFile "..\${SNAME}.exe"

LoadLanguageFile "${NSISDIR}\Contrib\Language files\English.nlf"

VIProductVersion "0.1.0.0"
VIAddVersionKey /LANG=${LANG_ENGLISH} "ProductName" "Portable ATITool Launcher"
VIAddVersionKey /LANG=${LANG_ENGLISH} "LegalCopyright" "ATITool © 2004-2007 W1zzard"
VIAddVersionKey /LANG=${LANG_ENGLISH} "FileDescription" "ATITool"
VIAddVersionKey /LANG=${LANG_ENGLISH} "FileVersion" "0.26"

Section "Main"

	CopyFiles /SILENT "$EXEDIR\appdata\ATITool.sys" "$SYSDIR\drivers"
	CopyFiles /SILENT "$EXEDIR\appdata\ATITool64.sys" "$SYSDIR\drivers"
	CopyFiles /SILENT "$EXEDIR\appdata\ATITool.inf" "$WINDIR\Inf"

	${registry::RestoreKey} "$EXEDIR\portable\driver.reg" $R0
	Sleep 300
	${registry::RestoreKey} "$EXEDIR\portable\TechPowerUp.reg" $R0
	Sleep 200
	${registry::RestoreKey} "$EXEDIR\portable\MUI.reg" $R0
	Sleep 200
	ExecWait "$WINDIR\Inf\ATITool.inf"
	Sleep 500

	ExecWait "$EXEDIR\Appdata\ATITool.exe"

;-----Cleaning up------
	CopyFiles /SILENT "$SYSDIR\drivers\ATITool.sys" "$EXEDIR\appdata\"
	CopyFiles /SILENT "$SYSDIR\drivers\ATITool64.sys" "$EXEDIR\appdata\"
	Sleep 500
	Delete "$SYSDIR\drivers\ATITool.sys"
	Delete "$SYSDIR\drivers\ATITool64.sys"
	Delete "$WINDIR\Inf\ATITool.inf"

;-----Cleaning up------

	${registry::RestoreKey} "$EXEDIR\portable\RegClean.reg" $R0
	
	
SectionEnd

im not sure i have all the information in the registry so i tried to get the inf to run to install the files after they are all copied over to the right places. mabe im doing it wrong? anyone or w1zzard have any idea?

 

[W1zzard]

i dont think that works .. there is an nsis plugin for driver installation .. that's what i'm using

 InstDrv::InitDriverSetup /NOUNLOAD "{85B5DDD0-E090-4B15-BDF2-A443A3CA0B66}" "*ATIToolDevice"
	
  Pop $0
  DetailPrint "Driver setup: started"
  InstDrv::DeleteOemInfFiles /NOUNLOAD
  Pop $0
	StrCmp $0 "00000103" 0 +3
  Goto +2
  DetailPrint 'Old .INF files: removed ($0)'

  InstDrv::RemoveAllDevices /NOUNLOAD
  Pop $0
	StrCmp $0 "00000000" 0 +3
	DetailPrint 'Old devices: removed'
  Goto +2
  DetailPrint 'Old devices: could not remove ($0)'
  
  InstDrv::CreateDevice /NOUNLOAD
  Pop $0
	StrCmp $0 "00000000" 0 +3
	DetailPrint 'New device: created'
  Goto +2
  DetailPrint 'New device: could not create ($0)'
  
  DetailPrint "Installing driver from: $TEMP\ATITool.inf"
  InstDrv::InstallDriver /NOUNLOAD "$TEMP\ATITool.inf"

  Pop $0 ; return error/success
	StrCmp $0 "00000000" 0 +3
	DetailPrint 'New device driver: installed'
  Goto +2
  DetailPrint 'New device driver: could not install ($0)'
  
  Pop $0 ; return error/success
	StrCmp $0 "0" 0 +3
	DetailPrint 'New device: started'
  Goto +2
  DetailPrint 'New device: could not start ($0)'

 

[MindlessOath]

ok i will try that out. i think the plugin is Instdrv.zip
if im not mistaken. i will try that out. thanks for the help!

i will get back to ya when i figure this out or need some more help.

EDIT: SEEMS TO HAVE WORKED, WILL TEST IT ON SOME UNITS FIRST! thanks!

 

[MindlessOath]

The final version here: http://rapidshare.com/files/37248739/Portable_ATITool.exe.html
this will transfer files to the $temp folder on the hdd, then write some data to the registry and then install the driver to run ati tool.
after its closed it will then delete the regisry files (theirby also uninstall the driver i belive) delete the $temp folder files (the ones only extracted by this application), and then delete the driver files in the $sysdir that were installed there by this application.

there may be one or two things that get left behind, im not 100% sure, but it does what i want it too and run without installing and leaving traces for the end user to see, ie i can do my testing and get it out of here asap.